MacWorld 2000 January/Macworld (2000-01).dmg/Updaters/DirXtra HTML204/xtradoc.dir/00023_Script_HTML-Xtra Scripts

Text File | 1999-02-22 | 10KB | 338 lines

-- HTML-XTRA Scripts
--
-- These handlers show some examples, how to include #html members into
-- Your project and how to take care of it
--
-- (c) 1998-1999, Stefan Schmidt-Bilkenroth (ssb) / Media Connect
--

--------------------------------------------------------------------------------
--
-- htmlregister
--
-- This handler calls the registration method
--
--------------------------------------------------------------------------------

on htmlregister mem
  -- Register the xtra once, before it appears on the stage
  -- to avoid "unregistered" messages
  -- enter Your registration code here and un-comment
  -- Register( member mem, string( 1234 ))
end


--------------------------------------------------------------------------------
--
-- htmlstartmovie
--
-- This handler should be called from Your startmovie script
--
--------------------------------------------------------------------------------

on htmlstartmovie
  -- declare the globals
  global ghtmlnormfont, ghtmlheadfont, ghtmlttfont, ghtmlfontsize, ghtmlpath, glasturl
  global ghtmllinkred, ghtmllinkgreen, ghtmllinkblue, ghtmlsmoothness, ghtmlmargin
  global gmac, gsep

  -- perform the registration
  htmlregister ("html")

  -- setup of initial values, be aware of crossplatform playback!!
  if gmac then -- we are on macos platform
    set ghtmlnormfont = "Times" -- my default font for normal text
    set ghtmlttfont = "Courier" -- my default font for teletype text
    set ghtmlheadfont = "Helvetica"  -- my default font for header text
    set ghtmlfontsize = 9 -- my base for the fontsize calculations
    set ghtmlpath = the moviepath -- the directory of the html files
  else
    set ghtmlnormfont = "Times Roman" -- my default font for normal text
    set ghtmlttfont = "Courier New" -- my default font for teletype text
    set ghtmlheadfont = "Arial"  -- my default font for header text
    set ghtmlfontsize = 11 -- my base for the fontsize calculations
    set ghtmlpath = the moviepath -- the directory of the html files
  end if

  -- setup the default link color, default is red
  set ghtmllinkred = 255
  set ghtmllinkgreen = 0
  set ghtmllinkblue = 0

  -- setup default values for margin and smoothness
  set ghtmlsmoothness = 0
  set ghtmlmargin = 5

  -- tell the cast member
  htmlsetdefaults "html"
end


--------------------------------------------------------------------------------
--
-- htmlsetdefaults
--
-- Setup the font defaults and link color
--
--------------------------------------------------------------------------------

on htmlsetdefaults mem
  -- declare globals
  global ghtmlnormfont, ghtmlheadfont, ghtmlttfont, ghtmlfontsize
  global ghtmllinkred, ghtmllinkgreen, ghtmllinkblue, ghtmlsmoothness, ghtmlmargin

  -- setup the default fonts for the text parts
  repeat with i = 1 to 7
    setdefault( member mem, "NORM"&string(i), ghtmlnormfont, ghtmlfontsize+i )
    setdefault( member mem, "TT"&string(i), ghtmlttfont, ghtmlfontsize+i )
    if i < 7 then -- only 6 HEAD tags available
      setdefault( member mem, "HEAD"&string(i), ghtmlheadfont, ghtmlfontsize+20-(3*i) )
    end if
  end repeat

  -- setup the link color
  setlinkcolor( member mem, ghtmllinkred, ghtmllinkgreen, ghtmllinkblue )

  -- setup smoothness and margin
  set the scrollsmooth of member mem = ghtmlsmoothness
  set the margin of member mem = ghtmlmargin
end


--------------------------------------------------------------------------------
--
-- htmlredraw
--
-- Force the cast member to redraw its content
--
--------------------------------------------------------------------------------

on htmlredraw mem
  -- just a siple hack
  set the html of member mem = the html of member mem
end


--------------------------------------------------------------------------------
--
-- htmlclear
--
-- Clears the content of the cast member
--
--------------------------------------------------------------------------------

on htmlclear mem
  -- simply erase the html of the cast member
  set the html of member mem = empty
end


--------------------------------------------------------------------------------
--
-- htmlload
--
-- Low level load handler, that uses FileIO to import the html source
--
--------------------------------------------------------------------------------

on htmlload mem, file
  -- show "Watch" cursor
  cursor 4

  -- open FileIO
  set myfile = new( xtra "FileIO" )

  -- open the file
  openfile( myfile, file, 1 )

  -- error handling
  if (status(myfile)) then
    set source = "<HTML><BODY><P><B>Error opening file:</B><BR>"&file&"<BR><A HREF=" "e&"index.htm" "e&">return to Table of contents.</A></P></BODY></HTML>"
  else
    -- read in the file
    set source = readfile( myfile )

    -- error handling
    if (status(myfile)) then
      alert "Error while reading from file:"&return&file
      set source = empty
    end if

    -- close the file
    closefile( myfile ) -- close the file
  end if

  -- clear the instance of FileIO
  set myfile = void -- Free the FileIO instance

  -- set the content of the cast member
  set the html of member mem = source

  -- Free the space occupied by html source
  set source = void

  -- switch back to "mouse" cursor
  cursor -1
end


--------------------------------------------------------------------------------
--
-- htmldolinkabs
--
-- Follow an absolute link
-- the link contains the complete pathname, based on ghtmlpath
--
--------------------------------------------------------------------------------

on htmldolinkabs mem, url
  -- declare globals
  global glasturl, ghtmlpath

  -- save the url for use with relative links
  set glasturl = url

  -- get the complete OS specific path of the link file
  set path = ghtmlpath & url2path( glasturl )

  -- load it
  htmlload mem, ghtmlpath & url2path( glasturl )
end


--------------------------------------------------------------------------------
--
-- htmldolinkrel
--
-- Follow an relative link
-- resolves the relative link to an absolute link
-- and then calls htmldolinkabs
--
--------------------------------------------------------------------------------

on htmldolinkrel mem, url
  --declare globals
  global glasturl, gmac, gsep

  -- get the absolute path from the relative link
  set url = concaturl( glasturl, url )

  -- just do the absolute link
  htmldolinkabs mem, url
end


--------------------------------------------------------------------------------
--
-- htmlgetmeta
--
-- A simple sample handler that shows an example, how to retrieve the
-- contents of the <META ...> tags.
--
--------------------------------------------------------------------------------

on htmlgetmeta
  global metalist
  set metalist = []
  set metalist = the metalist of member "html"
  set metacount = count(metalist)
  set str = empty
  if metacount then
    repeat with i = 1 to metacount
      if i > 1 then set str = str & return
      set str = str & char 1 to i of "        " & getat(getat(metalist,i),1) & " ("&getat(getat(metalist,i),2)&")"
    end repeat
  end if
  set the text of field "meta" = str
end

--==============================================================================
--
-- Auxilary Handlers
--
--==============================================================================

--------------------------------------------------------------------------------
--
-- Url2Path
--
-- This handler converts the url string to a valid pathname
--
--------------------------------------------------------------------------------

on URL2Path url
  global gmac, gsep
  set path = empty
  set olddel = the itemdelimiter
  set the itemdelimiter = "/"
  set cnt = the number of items of url
  repeat with i = 1 to cnt
    if i > 1 then set path = path & gsep
    set path = path & item i of url
  end repeat
  set the itemdelimiter = olddel
  return path
end


--------------------------------------------------------------------------------
--
-- ConcatURL
--
-- This handler returns the destination file path, when you pass the actual
-- file URL and the relative link URL. This handler checks for "UpDirectory"
-- links ("..")
--
--------------------------------------------------------------------------------

on ConcatURL base,link
  global gsep
  set baselist = []
  set linklist = []
  set url = empty
  set olddel = the itemdelimiter
  set the itemdelimiter = "/"
  -- convert url to lists
  set basecnt = the number of items of base
  repeat with i = 1 to basecnt
    add( baselist, item i of base )
  end repeat
  set linkcnt = the number of items of link
  repeat with i = 1 to linkcnt
    add( linklist, item i of link )
  end repeat
  -- strip last (filename) of base to get path
  deleteat( baselist, basecnt )
  set basecnt = count( baselist )
  -- do the .. up directory
  repeat while getat( linklist, 1 ) = ".."
    deleteat( baselist, basecnt )
    set basecnt = count( baselist )
  end repeat
  set linkcnt = count( linklist )
  repeat with i = 1 to linkcnt
    addat( baselist, count( baselist )+1, getat( linklist, i ))
  end repeat
  set basecnt = count ( baselist )
  repeat with i = 1 to basecnt
    if i > 1 then set url = url & the itemdelimiter
    set url = url & getat( baselist, i )
  end repeat
  set the itemdelimiter = olddel
  return url
end

on convertpc2url str
  set olddel = the itemdelimiter
  set the itemdelimiter = "\"
  set anz = the number of items of str
  set res = empty
  repeat with i = 2 to anz
    if i > 2 then set res = res & "/"
    set res = res & item i of str
  end repeat
  set the itemdelimiter = olddel
  return res
end